SaveAsIcalを発行するVBscript

前に、Outlook予定表とGoogleカレンダーの同期ができなくなったので、そして、Outlookの予定表をiCalender形式で出力し、それをGoogleカレンダーでインポートすることにし、そのための簡単なVBscriptを作って利用していると書いた。

そうしたら、通りすがりの方から、"ECOというソフトを使って、グーグルの連絡帳とカレンダーを同期できる"というコメントをいただいた。ブログで文句を言うと答えてくれる人がいる、感謝々々である。
もっとも、今のところ職場のポリシーの関係もあって、前に書いたように、未だ手作業同期を続けている。
で、私が使っているスクリプトも、どなたかのご参考になるかと思って、以下に示しておく。
なお、筆者はこのスクリプトを "SaveAsIcal.vbs"という名前でデスクトップに置いて使っている(従ってicsファイルはデスクトップに出力される)。
'■SaveAsIcalメソッドによる、OutlookカレンダーのiCalender形式での出力
' 起動後、出力対象日付入力(デフォルトは本日から31日間)
' 出力先は本スクリプトのあるフォルダ内に "@outlook.ics" として

Dim objWS
Set objWS = WScript.CreateObject("WScript.Shell")

Const olFolderCalendar = 9
Const olFullDetails = 2
Const olFreeBusyAndSubject = 1 'こちらは使わない

Dim OlApp 'Outlook.Application
Dim OlNmSp 'Outlook.NameSpace
Dim OlEx 'CalendarSharing
Dim objF

Dim DSTR

SD = Date
ED = DateAdd("d", 31, SD)
SED = InputBox("SaveAsICal", "StartDate-EndDate", SD & "-" & ED)
DSTR = Split(SED, "-")

Set OlApp = CreateObject("Outlook.Application")

Set OlNmSp = OlApp.Session
Set objF = OlNmSp.GetDefaultFolder(olFolderCalendar)
Set OlEx = objF.GetCalendarExporter

With OlEx
.CalendarDetail = olFullDetails '全詳細情報
.IncludeWholeCalendar = False '日付指定に従う
.RestrictToWorkingHours = False '勤務時間に限らない
.IncludeAttachments = True '添付あり(但し、Google側は受けられない)
.IncludePrivateDetails = True 'プライベート情報含む
End With

OlEx.StartDate = DSTR(0)
OlEx.EndDate = DSTR(1)

'このスクリプトがあるフォルダにiCalender形式で出力する
OlEx.SaveAsIcal (objWS.CurrentDirectory & "\@outlook.ics")

'OlApp.Quit    'Outlookを終了させる場合
OlApp = Null

MsgBox "SaveAsICal finished" & vbCrLf & SED

'Firefoxを起動してGoogleカレンダーの設定画面を開く。他ブラウザならプログラム名を変更
objWS.Run """c:\Program Files\Mozilla Firefox\firefox.exe"" -new-tab https://www.google.com/calendar/render#i"

本ページのソース部分をコピー/ペーストするか、下記リンクからダウンロード。(但し、動作保証はいたしません)

SaveAsIcal.vbs ファイルはこちら

関連記事
スポンサーサイト

コメントの投稿

非公開コメント

No title

ソースの公開ありがとうございます。
googleへのインポートが楽になりました。

Re: No title

お役にたてば幸いです。
見たまんまのソースですので、使いやすいように手を入れて使ってください。
Gallery
検索フォーム

⇒記事一覧

プロフィール

六二郎。六二郎。


定年退職
苦しい家計の足しに再就職
=いつクビになってもええねん
 言うたもん勝ちや!のブログ
リンク
最新記事
最新コメント
最新トラックバック
アーカイブ
カテゴリ
タグ

ITガジェット 書評 マイナンバー Audio/Visual 

リンク
現在の閲覧者数
聞いたもん